将博客迁移到 Org-mode

(defun my-blog-post-metadata ()
  (let ((posts-dir (expand-file-name "~/org/blog/posts/")))
    (delq nil
          (mapcar
           (lambda (file)
             (with-temp-buffer
               (insert-file-contents file nil 0 2000)
               (let (title tags-str category date description)
                 (goto-char (point-min))
                 (when (re-search-forward "^#\\+title:[ \t]*\\(.+\\)$" nil t)
                   (setq title (string-trim (match-string-no-properties 1))))
                 (goto-char (point-min))
                 (when (re-search-forward "^#\\+filetags:[ \t]*\\(.+\\)$" nil t)
                   (setq tags-str (match-string-no-properties 1)))
                 (goto-char (point-min))
                 (when (re-search-forward "^#\\+category:[ \t]*\\(.+\\)$" nil t)
                   (setq category (string-trim (match-string-no-properties 1))))
                 (goto-char (point-min))
                 (when (re-search-forward "^#\\+date:[ \t]*<\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)" nil t)
                   (setq date (match-string-no-properties 1)))
                 (goto-char (point-min))
                 (when (re-search-forward "^[ \t]*:SUMMARY:[ \t]*$" nil t)
                   (let ((start (1+ (match-end 0))))
                     (when (re-search-forward "^[ \t]*:END:[ \t]*$" nil t)
                       (setq description (string-trim (buffer-substring-no-properties start (match-beginning 0)))))))
                 (when title
                   (list :file file :title title
                         :tags (when tags-str (split-string tags-str ":" t))
                         :category category :date date :description description)))))
           (directory-files posts-dir t "\\.org$")))))

(defun my-blog-generate-index (index-file title-str keyword-fn &optional reverse)
  (let* ((index-dir (file-name-directory index-file))
         (flat (seq-mapcat
                (lambda (post)
                  (mapcar (lambda (key) (cons key post))
                          (funcall keyword-fn post)))
                (my-blog-post-metadata)))
         (grouped (sort (seq-group-by #'car flat)
                        (if reverse
                            (lambda (a b) (string> (car a) (car b)))
                          (lambda (a b) (string< (car a) (car b)))))))
    (make-directory index-dir t)
    (with-temp-file index-file
      (insert (format "#+title: %s\n" title-str))
      (insert "#+options: ^:{}\n\n")
      (pcase-dolist (`(,key . ,entries) grouped)
        (insert (format "** %s\n:PROPERTIES:\n:CUSTOM_ID: %s\n:END:\n\n"
                        key (my-blog-slugify key)))
        (dolist (post (sort (mapcar #'cdr entries)
                            (lambda (a b)
                              (let ((da (plist-get a :date))
                                    (db (plist-get b :date)))
                                (if (and da db) (string> da db) (not da))))))
          (insert (format "- [[file:%s][%s]]\n"
                          (file-relative-name (plist-get post :file) index-dir)
                          (plist-get post :title))))
        (insert "\n")))))

(defun my-blog-generate-tag-index (&optional _project)
  (my-blog-generate-index
   (expand-file-name "~/org/blog/tags/index.org")
   "标签"
   (lambda (post) (plist-get post :tags))))

(defun my-blog-generate-homepage (&optional _project)
  (let* ((index-file (expand-file-name "~/org/blog/index.org"))
         (index-dir (file-name-directory index-file))
         (posts (sort (seq-filter (lambda (post) (plist-get post :date))
                                  (my-blog-post-metadata))
                      (lambda (a b) (string> (plist-get a :date) (plist-get b :date))))))
    (with-temp-file index-file
      (insert "#+title: 13m0n4de's blog\n")
      (insert "#+options: ^:{} toc:nil\n\n")
      (dolist (post posts)
        (let* ((file  (plist-get post :file))
               (title (plist-get post :title))
               (category    (plist-get post :category))
               (date        (plist-get post :date))
               (description (plist-get post :description))
               (parts   (split-string date "-"))
               (date-cn (format "%s年%d月%d日"
                                (nth 0 parts)
                                (string-to-number (nth 1 parts))
                                (string-to-number (nth 2 parts)))))
          (insert (format "* [[file:%s][%s]]\n"
                          (file-relative-name file index-dir)
                          title))
          (insert ":PROPERTIES:\n")
          (insert (format ":POST_DATE: %s\n" date-cn))
          (when (org-string-nw-p category)
            (insert (format ":POST_CATEGORY: %s\n" category)))
          (insert ":END:\n\n")
            (when (org-string-nw-p description)
              (insert (format "%s\n\n" description))))))))

(defun +org-html-headline (headline contents info)
    (let ((post-date (org-element-property :POST_DATE headline))
          (post-category (org-element-property :POST_CATEGORY headline)))
      (if post-date
          (let* ((title (org-export-data (org-element-property :title headline) info))
                 (href (replace-regexp-in-string
                        "\\.org$" ".html"
                        (or (org-element-map (org-element-property :title headline) 'link
                              (lambda (l) (org-element-property :path l)) info t)
                            "")))
                 (meta (if post-category
                           (format "%s · 分类于 <a href=\"/categories/#%s\">%s</a>"
                                   post-date (my-blog-slugify post-category) post-category)
                         post-date)))
            (format "<article class=\"post-summary\">\n<p class=\"post-meta\">%s</p>\n<h2>%s</h2>\n%s<a href=\"%s\" class=\"read-more\">继续阅读</a>\n</article>\n"
                    meta title (or contents "") href))
        (org-html-headline headline contents info))))